Hey check out this sword model that I made in MED. My first really good model that I have made and skinned myself. It has 8 different skins, some with runes on the blade. I also added a fire halo effect, and it leaves trails when you attack.

Looks cool, also the effects!^_^

Woah! Nice affects! and nice sword also, A little hard to see it though small pic.

Here's a bigger pic, with just the sword in all of its skins + the particles. Ya big baby! LOL

Will you tell us the Code of the effects?

Mabe we'll lern something out of it...

you can do this with attach function and a particle stream (see manual attaching light to a model) but this is a very fps eating method.

the best way is a afterglow shader...fast and easy to manipulate, though you need the shader first

nice swords
cheers

i used the attach function to attach the sword to the dwarf. but the particles were done with this code:

//junk n stuff
define hilt,skill1;
define tip,skill2;

var chop_off;
var end_vec[3];
var start_vec[3];
var part_angle[3];
var line_length;



//fades the particle
function fire_update()
{
my.alpha -= 3 * time;
if (my.alpha<=0) {my.lifespan=0;return;}
}

//the controls the actual particle
function fire_burn()
{
my.x += random(3) + -2;
my.y += random(3) + -2;
my.z += random(3) + -1;
my.size = 8;
my.vel_x = (random(0.4) - 0.2) * 3;
my.vel_y = (random(0.4) - 0.2) * 3;
my.vel_z = (random(0.4) - 0.2) * 3;
my.move = on;
my.bmap = fire_part;
my.flare = on;
my.bright = on;
my.alpha = random(10)+5;
my.function = fire_update;
}

//the code that creates the halo
function fire_halo(strength)
{
weapon.bright = on;
weapon.ambient = 100;
weapon.albedo = 100;
vec_for_vertex(end_vec,weapon,weapon.hilt);
vec_for_vertex(start_vec,weapon,weapon.tip);
line_length = vec_dist(end_vec.x,start_vec.x);
vec_diff(part_angle,end_vec.x,start_vec.x);
chop_off = line_length/2;
vec_normalize(part_angle,2);
while(chop_off > 0)
{
effect(fire_burn,strength,start_vec,start_vec);
weapon.lightred = 200;
weapon.lightgreen = 128;
weapon.lightblue = 0;
weapon.lightrange = 100;
vec_add(start_vec.x,part_angle.x);
chop_off -=1;
wait(1);
}
}

//uses hilt,tip
action weapon_av
{
my.tip = 16;
my.hilt = 211;
weapon = me;
while(1)
{
fire_halo(1);
wait(1);
}
}

Ok the weapon_av action is the action I use on the sword. The "my.tip" skill is the vertex of the tip of the sword and the "my.hilt" is the base vertex of the blade. Set it custom to your model. In "fire_halo(1)" the "1" is the strength of the particles, or how many are created every tick or whatever, set it to 100 and blow up your computer!

The trails is just a special action that I made that when the player attacks a transparent model is created every tick (or whatever) and it waits like 4 ticks (or whatever) and remove itself. BTW I've never had any trouble with fps.

I really was planning on sharing this with everyone because of you Star Wars gurus out there. It can be modified to create a cool lightsaber effect.

Yea the swords are sweet.

Very nice. Excellent effects. I love it, an I was looking for that exact effect for my weapons in the game I creating. Very nice indeed.

Does this include the way you were able to make those awesome trails after the blade (the mouse-on-screen effect; with duplications of the sword trailing after to blade) in the first screenshot.

No it doesn't, the trails were a seperate thing, an experiment. In the game you won't get the flames and the trails together; the flames are for detecting enemies and secrets and the trails are for a super-sharp edge. There is a dwarf in my game, I got that model from Psonic's site and it is going to have alot of item customization such as forging your own weapon and using magic and different metals and runes to create prefixes and suffixes like diablo.

//the material for the trail
material mat_blue
{
diffuse_red = 0;
diffuse_green = 0;
diffuse_blue = 255;
specular_red = 0;
specular_green = 0;
specular_blue = 255;
power = 10;
}

//the action assigned to the trail model
action weapon_trail
{
my.material = mat_blue;
my.passable = on;
my.transparent = on;
my.alpha = 50;
my.bright = on;
my.flare = on;
my.skin = weapon.skin;
while(1)
{
vec_set(my.x,weapon.x);
my.pan = weapon.pan;
my.tilt = weapon.tilt;
my.roll = weapon.roll;
wait(4);
ent_remove(me);
return;
}
}

//my attack animation controller
if(my.state == _attack)
{
my.anim_per = 0;
while(my.anim_per < 100)
{
ent_create("sword1.mdl",my.x,weapon_trail);
my.anim_per += 10 * time;
ent_animate(me,"attack_aaa",my.anim_per,anm_add);
wait(1);
}
my.state = _idle;
}

Ok, this is a section from my animate_me() function that I use to animate the player and enemies using states that are defined before the function(that is; define _idle,0; define _attack,1;). Basically this part increases my.anim_per by 10, thus animating the model AND ent_creating my sword1.mdl and assigning weapon_trail to it. The weapon_trail waits for a new york minute then removes itself. The material is what makes it pretty. Look very closely before including it in your game, it may clash with your animation sceme thingy. Just place the ent_create in some sort of while loop WHILE your player is attacking. Also, there is the WEAPON entity pointer, in my game the weapon is a seperate model attached to the player via vertex attachment and the WEAPON entity pointer is assigned to the weapon model so that it may be referred to, change it to your weapon entity pointer.