Searching HLSL Terrain Multitexturing...

Posted By: Espér

Searching HLSL Terrain Multitexturing... - 05/10/10 13:55

I´ve looked at the Wiki.. but the link seems to be broken.:

Soo...

1.) Does someone have the shader on his HDD???
2.) Has someone an example on how to add more textures to it?

^^
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 14:33

Try this one:

Code:
float4x4 matWorld;
float4x4 matWorldViewProj;

float4 vecSunDir;
float4 vecAmbient;
float4 vecSunColor;
float2 tiles = {50,50};

texture entSkin1;

texture dmap1_bmap;
texture dmap2_bmap;
texture dmap3_bmap;
texture dmap4_bmap;
texture dmap5_bmap;

sampler2D blend = sampler_state {	Texture = <entSkin1>;mipfilter=2;minfilter=2;magfilter=2;};

sampler2D skin1 = sampler_state {	Texture = <dmap1_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin2 = sampler_state {	Texture = <dmap2_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin3 = sampler_state {	Texture = <dmap3_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin4 = sampler_state {	Texture = <dmap4_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin5 = sampler_state {	Texture = <dmap5_bmap>;mipfilter=2;minfilter=2;magfilter=2;};

void VS (	in float4 iPos : POSITION,
		in float3 iNorm : NORMAL,
		in float4 iTex : TEXCOORD0,
		out float4 oPos : POSITION,
		out float3 oNorm : TEXCOORD1,
		out float4 oTex : TEXCOORD0)
	{
	oPos = mul (iPos,matWorldViewProj);
	oNorm = mul(iNorm,matWorld);
	oTex = iTex;
	}

float4 PS(	in float2 tex : TEXCOORD0,
		in float3 iNorm : TEXCOORD1) : COLOR {

	float4 map = tex2D(blend,tex);

	float4 color = tex2D(skin1,tiles * tex);
	color = lerp(color,tex2D(skin2,tiles * tex),map.r);
	color = lerp(color,tex2D(skin3,tiles * tex),map.g);
	color = lerp(color,tex2D(skin4,tiles * tex),map.b);
	color = lerp(color,tex2D(skin5,tiles * tex),map.a);

	color *= vecSunColor * saturate(dot(-vecSunDir, normalize(iNorm))) + vecAmbient;	
	return color;}

technique t{ pass p{	AlphaBlendEnable = 0;
			zWriteEnable = 1;
			VertexShader = compile vs_2_0 VS();		
			PixelShader = compile ps_2_0 PS();			
		}}


You have to define 5 BMAPs named dmap1...dmap5. The first skin of the terrain / model ist the blendmap.

dmap1 is the basecolor, dmap2,3,4 are RGB and dmap5 is Alpha.
This shader only supports the sun. But adding more lights is no problem (if you need them). You can add as many textures as the shader model supports (in a single pass). This is done by "splitting" the RGBA channels. You can use for example 4 textures per channel (would be 17 textures in one pass!) But there are restrictions (of course). You can't blend straight between all textures! If you use such a 17-texture-shader, i recommend to use the 4 textures per channel only as texture variations and not as completely different textures.

I hope you understand what i mean...

The same can be done by using more blendmaps.
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 14:41

i´m not really understanding that blendmap thing... Y_Y
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 15:00

The blendmap defines, where the 5 textures are "placed". This texture is not tiled.

Black means, that the base texture is rendered (dmap1)
red = dmap2
green = dmap3
blue = dmap4
and alpha channel = dmap5
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 15:10

hmm.. isn´t there a shader wich uses the vertex/Polygon height in the map for texturing?
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 15:49

yes, but the blendmap method is waaaayyyy more flexible.

Code:
float4x4 matWorld;
float4x4 matWorldViewProj;

float4 vecSunDir;
float4 vecAmbient;
float4 vecSunColor;
float2 tiles = {50,50};

texture dmap1_bmap;
texture dmap2_bmap;
texture dmap3_bmap;
texture dmap4_bmap;
texture dmap5_bmap;

sampler2D skin1 = sampler_state {	Texture = <dmap1_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin2 = sampler_state {	Texture = <dmap2_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin3 = sampler_state {	Texture = <dmap3_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin4 = sampler_state {	Texture = <dmap4_bmap>;mipfilter=2;minfilter=2;magfilter=2;};
sampler2D skin5 = sampler_state {	Texture = <dmap5_bmap>;mipfilter=2;minfilter=2;magfilter=2;};

void VS (	in float4 iPos : POSITION,
		in float3 iNorm : NORMAL,
		in float4 iTex : TEXCOORD0,
		out float4 oPos : POSITION,
		out float3 oNorm : TEXCOORD1,
		out float4 oTex : TEXCOORD0,
		out float y : TEXCOORD2)
	{
	oPos = mul (iPos,matWorldViewProj);
	oNorm = mul(iNorm,matWorld);
	oTex = iTex;
	y = mul(iPos,matWorld).y;
	}

float4 PS(	in float2 tex : TEXCOORD0,
		in float3 normal : TEXCOORD1,
		in float y : TEXCOORD2) : COLOR {

	float4 color = tex2D(skin1,tiles * tex);

	color = lerp(color,tex2D(skin2,tiles * tex),saturate((1500-y) / 100));
	color = lerp(color,tex2D(skin3,tiles * tex),saturate((1000-y) / 100));
	color = lerp(color,tex2D(skin4,tiles * tex),saturate((500-y) / 100));
	color = lerp(color,tex2D(skin5,tiles * tex),saturate(1-pow(normal.y,1)));	

	color *= vecSunColor * saturate(dot(-vecSunDir, normalize(normal))) + vecAmbient;	
	return color;}

technique t{ pass p{	AlphaBlendEnable = 0;
			zWriteEnable = 1;
			VertexShader = compile vs_2_0 VS();		
			PixelShader = compile ps_2_0 PS();			
		}}


you can (must) play around with the values in the pixelshader to fit your needs (example):

color = lerp(color,tex2D(skin2,tiles * tex),saturate((1500-y) / 100));

the 1500 is the height in quants and the 100 is the smoothness. The last texture is blended according to the surface normal. I'm not sure if this is what you looking for, but it's worth a try. You could also combine both techniques. (blendmap + height-dependend)
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:04

ok.. du you have an example for the blendmap (or an example model with the skins)? ( have no idea what such a thing should look like...)
Posted By: Uhrwerk

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:20

Thats an easy one. Imagine a plateau with a mountain in the center of it. Leave the blendmap black except for the center area, there you paint it red. Now define the base texture as a grass area and set the first map to a rocky one. The center area now gets the rock texture, the surrounding gets the grass texture.
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:24

ok...
My skins are now in the following order:

Skin1: Blendmap
Skin2: Stone-tex
Skin3: Dirt tex
Skin4: Grass Tex
Skin5: Sand tex


Ingame the complete terrain is just shown.. black...
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:36

no wonder... the names of your definded BMAPs in the script and in the shader must be identical.
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:39

i´ve defined the bitmaps like this:

BMAP* dmap1_bmap;
BMAP* dmap2_bmap;
BMAP* dmap3_bmap;
BMAP* dmap4_bmap;
BMAP* dmap5_bmap;


I think that are the same names.....
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:43

yes, but in the script, you must omit the "_bmap". This is just the A7 naming convention for shaders.

BMAP* dmap1 = "someTexture.tga";
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:44

ok.. i think i´m too stupid for this.. Y_Y
(or my english is not good enough *german*)
any demo..?
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 16:52

ich hab mir zwar die Shader im Wiki nie angeschaut (ich mach lieber alles selber, weil die meistens nix taugen) Aber vielleicht is dort irgendwo ein Projekt mit blendmap dabei...

Ich versuch's nochmal zu erklären:

du erstellst eine (leere) bitmap z.B. 1024x1024. Diese bitmap stellt KEINE Textur dar, sondern diehnt dem Shader nur dazu, festzustellen, wo die 5 Terrain-Texturen zu sehen sein sollen. Diese "Blendmap" gehört in Skin 1 des Terrains / Models.

Die 5 anderen Texturen (dmap1 ... dmap5) sind die "richtigen" Texturen. Die namen haben zwar nicht unbeding eine Bedeutung, aber so ist es einfacher, später die Texturen (auch zur Laufzeit) auszutauschen.

Also alles was ins skript gehört is:

BMAP* dmap1 = "SomeTexture.tga";
BMAP* dmap2 = "SomeTexture.tga";
BMAP* dmap3 = "SomeTexture.tga";
BMAP* dmap4 = "SomeTexture.tga";
BMAP* dmap5 = "SomeTexture.tga";

und selbstverständlich muss dem Terrain/Model der shader zugewiesen werden. Das wichtigste is die blendmap. Aber selbst wenn diese leer ist, müsste die Erste textur zu sehen sein (dmap1).
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:06

ok.. ich hab ne blendmap gemacht.. und sie dem model gegeben.. aber iwie wird nur 1 der texturen angezeigt (dmap5).. Y_Y
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:17

die Textur MUSS 32 bit sein, sonst wird immer die letzte Textur dargestellt (aus irgendwinem Grund wird "kein Alpha" als "100% Alpha" interpretiert...)
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:19

ist 32Bit TGA...

bauch ich nen Alpha Kanal????
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:22

ja. Aber nicht komplett weiß, sonst ist der Effekt der selbe wie ohne Alphakanal. Der Alphakanal wird genauso wie die 3 Farben verwendet.
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:31

ok.. das hab ich bisher rausgefunden:

BMAP* dmap1 = "01_stone.tga"; //Rot
BMAP* dmap2 = "01_dirt.tga";
BMAP* dmap3 = "02_grass.tga"; //Grün
BMAP* dmap4 = "01_grass.tga"; //Blau
BMAP* dmap5 = "01_sand.tga"; //Alpha

Wie mach ich das er dmap2 verwendet???
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:37

sieht aus, als hättest du da 2 Texturen doppelt oder vertauscht.

dmap1 = schwarz (die textur wird quasi überall gerendert)
dmap2 = rot
dmap3 = grün
dmap4 = blau
dmap5 = alpha
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:42

dmap2 wird nicht verwendet..

wenn ich dmap1 schwarz mache.. hab ich statt fels überall schwarze stellen...
dmap2 hat keine sinn.. es wird einfach nix angezeigt...
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:49

ok.. habs.. irgendwie....

allerdings brauch ich noch 2 weitere texturen...

wie funzt das???
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 17:56

entweder eine 2. Blendmap (skin2 im Model/Terrain) oder die Variante, die ich anfangs erwähnt hab (mit den Einschränkungen, dass man die "Sekundärtexturen" nicht direkt überblenden kann, ohne erst über die Primärtexturen zu gehen.

Allerdings - wenn die zusätzlichen Texturen ähnlich sind, dürfte das kein großes problem sein.
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 18:06

nich unbedingt ähnlich..
ich brauch halt sehr viele versch. Grundtexturen...

Gibt´s nen wegd as ich die Texturen der Ebene als Skin mache ( ganz normales model skinnen ).. und mittels shader dann berge, hänge..etc.. texturiere??? ( Der shader müsste dann halt den boden frei lassen)..
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 18:16

ja. Mehrere Möglichkeiten:

1) du musst den Alphakanal der Blendmap "opfern" um damit festzulegen, an welchen Stellen der Shader eingreifen soll
ODER
2) du teilst das Terrain in 2 Teile auf (aber dann ist der Übergang nicht mehr weich)
ODER
3) der Shader wird abhängig von der Oberflächennormalen ausgeblendet, so dass überall, wo es ebenerdig is, kein Shader gerendert wird (allerdings ist das nicht sicher genug, denn auch auf der Ebene können kleine Hügel auftreten, auf denen dann wieder der Shader dargestellt werden würde)

Punkt 1 und 3 haben den Nachteil, dass das Terrain dann 2 mal komplett gerendert werden muss.
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 18:24

arg viel anders als in punkt 1 wird´s ned gehn..

ich rbauch (beispielsweise ) für eine graslandschaft..
3-4 Grasarten.. einen weg oder straße... erdlöcher...etc

und das alls auf der erde...
so benötige ich eigentlich nur 3 skins für den shader..
der mir halt felsen..etc.. skinnt...

Fraglich ist.. wie langsam wird er mit variante 1...?
Posted By: muffel

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 18:30

kann man nicht versuchen auf einen Farbkanal 2 Texturen, die sich nie überblenden, zu packen
würde dann irgendwie sowas bedeuten:
bei 255 die zweite Textur voll da
bei 128 keine der beiden Texturen
bei 0 die erste TExtur voll da


weiß nicht ob das funktionieren könnte(kenn mich nicht mit shadern aus)

muffel
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 18:33

Wenn du viele Texturvariationen brauchst (3-4 Grasarten, wie du sagst), dann wäre ja fast die Methode, die ich am Anfang irgendwo erwähnt hab, das Mittel der Wahl. Damit kannst du pro kanal 4 Texturen verwenden. Das wären dann 17 Texturen. Aber diese müssen nach variation Gruppiert werden, denn man kann (wie schon mehrfach erwähnt) nicht von z.B. "rot 4" direkt auf "grün 4" überblenden. Dazwischen befindet sich IMMER ein schmaler bereich, in dem alle dazwischenliegenden Texturen zu sehen sind (oder besser gesagt: ein Mix aus allen dazwischenliegenden Texturen)... Aber ich hab mit meinen Tests festgestellt, dass diese Methode die beste ist, solange die Texturen in ähnlichen Gruppen zusammengefasst werden.

Der Vorteil is, dass das alles in einen einzigen Renderdurchgang passt.

@muffel: exakt das, was ich Eingangs erwähnt hab. Rein theoretisch kann man pro farbkanal 255 Texturen verwenden. Das wären dann 1024 Texturen. Allerdings unterstützt das weder eine Grafikkarte noch irgendein Shader-Model in einem Renderdurchgang smile !
Posted By: Widi

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 19:54

Sorry das ich mich hier einmische. Habe eine Frage an wdlmaster. Ich habe einen Terrainshader mit 7 texturen. Wie berechnest du die zusätzlichen texturen beim splitten des alphakanals? (alpha 0 - 127 = textur1, 128 - 255 = textur2)
Code:
float4 color = tex2D(sTex8, In.Tex7);
	color = lerp(color,tex2D(sTex5, In.Tex4),BlendColor.r);
	color = lerp(color,tex2D(sTex6, In.Tex5),BlendColor.g);
	color = lerp(color,tex2D(sTex7, In.Tex5),BlendColor.b);
	
	color = lerp(color,tex2D(sTex9, In.Tex4),saturate(BlendColor.r - BlendColor.a));
	color = lerp(color,tex2D(sTex10,In.Tex5),saturate(BlendColor.g - BlendColor.a));
	color = lerp(color,tex2D(sTex11,In.Tex7),saturate(BlendColor.b - BlendColor.a));


@Esper: So wie wdlmaster erklärt hat funktioniert das was du willst...
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 20:00

das kommt auf die Anzahl der Texturen an, die du in einem Kanal unterbringen willst (maximal 4, denn es werden nur 16 Texturzugriffe unterstützt!)

bei 2 Farben:
color = lerp(color,tex2D(skin1,tex),saturate(BlendColor.r*2));
color = lerp(color,tex2D(skin2,tex),saturate(BlendColor.r*2-1));

bei 4 Farben:
color = lerp(color,tex2D(skin1,tex),saturate(BlendColor.r*4 ));
color = lerp(color,tex2D(skin2,tex),saturate(BlendColor.r*4-1));
color = lerp(color,tex2D(skin3,tex),saturate(BlendColor.r*4-2));
color = lerp(color,tex2D(skin4,tex),saturate(BlendColor.r*4-3));

aber: es gelten die (ganz) oben genannten Einschränkungen!

Posted By: Widi

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 20:02

Genau was ich wollte. Danke vielmals. smile smile smile
Posted By: Espér

Re: Searching HLSL Terrain Multitexturing... - 05/10/10 22:09

ne.. nicht wirklich..
Langsam glaubich das die Mappingart mit A7 kaum möglich ist.. ohne schlechte texturquali zu verursachen...

Ich glaub ich berede das ma mit wdlmaster per PN weiter XD
Posted By: Uhrwerk

Re: Searching HLSL Terrain Multitexturing... - 05/11/10 12:57

Was hat das denn jetzt mit der Texturqualität zu tun?
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/11/10 13:22

rein garnichts! Ich werde im Laufe des Tages (eventuell) mal eine kleine Terrain-Demo mit einem 9-Texture-Shader hochladen (ein Gras-Shader dürfte auch dabei sein). Dann wird man sehen, dass selbst mit der A7 eine einigermaßen ordentliche Landschaft kein Problem ist...
Posted By: Uhrwerk

Re: Searching HLSL Terrain Multitexturing... - 05/11/10 14:09

Das ist eine ganz hervorragende Idee von Dir! laugh
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/11/10 21:39

hier!
http://www.file-upload.net/download-2509391/terrain.cd.zip.html

W,A,S,D,(E,Q) = Kamera bewegen
rechte Maustaste = Kamera drehen
linke Maustaste = auf Terrain malen
Mausrad = Radius (in Texel) einstellen
1...9 = Textur auswählen
F5 = Blendmap speichern
F7 = Blendmap laden
G = Gras-Shader anzeigen/ausblenden

Den Gras-Shader würde ich nicht für "ernste" Zwecke verwenden. Denn der ist mit seinen 30 Renderdurchgängen alles andere als Schnell smile
Posted By: Widi

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 09:40

Finde die Funktion zum malen auf das Terrain (in die Blendmap) super. Wie hast du das gemacht? Ich kenne den Befehl "pixel_to_bmap", aber wie hast du das mit dem Radius gemacht?
Posted By: Hummel

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 11:25

Originally Posted By: wdlmaster
(aus irgendwinem Grund wird "kein Alpha" als "100% Alpha" interpretiert...)

100% sichtbar war schon immer 100% Alpha wink
Wenn mans also genau nimmt gibt Alpha die Undurchsichtigkeit an und nich die Transparenz (bzw die dann nur indirekt).

In die Blendmap sollte übrigens besser additiv reingemalt werden.
Das verhinter, dass beim Übergang von 2 Farben für den Saum eine
falsche Textur reingeblendet wird.

Gras sollte besser durch Sprites dargestellt werden. Sieht eher wie ein ganz feines Fell aus oder Schimmel. tongue

Viel zu lernen du noch hast wdlmaster.
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 12:02

additiv?! nein! Da kann ich nur "in eine Richtung" blenden... wenn ich dann die 3 Farben übereinander liegen hab (weiß), wie soll ich mit Addition dann wieder auf schwarz, oder irgend eine andere Farbe kommen ?!

Und das Problem mit dem Saum löst du auch nicht! Zumindest nicht in diesem Shader, der 2 oder mehr Texturen pro Kanal verwendet. Es ist unmöglich von einer Farbe "höherer Ebene" direkt in eine andere Farbe "höherer Ebene" (rot4 direkt zu grün4) zu blenden! Im shader ist die Reihenfolge nunmal festgelegt.

Aber du wirst mir sicherlich einen Shader anbieten können, der JEDE beliebige kombination erlaubt. Wenn ja, dann nehme ich gern alles bisher gesagte zurück ...

Und der Grasshader - ist ein Fellshader, nur für Gras misbraucht. Dass man sowas in kein Spiel einbaut ist mir schon bewusst.
Posted By: Hummel

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 12:49

Ich könnte dir lang und breit erklären warum additiv, aber da du alles besser weißt spar ich mir das. 2 Farben pro Kanal geht auch, genauso wie man mehrere Kanäle zusammen verwenden kann um einen Wert von hoher Genauigkeit zu speichern, kann man auch einen einzelnen aufsplitten. Dass das mit einem gewissen Aufwand verbunden ist, sollte klar sein, aber man muss nur ein wenig Ahnung bezüglich binärer Zahlendarstellung haben.

Immerwieder schön zu sehen wie der Nachwuchs so unheimlich lernbereit reagiert.
Posted By: wdlmaster

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 13:25

du brauchst dich hier nicht so zu profilieren, mein "Freund"! Du hörst dich nämlich schon genauso arrogant an, wie vor einigen Jahren die damaligen Shader-Gurus Steempipe und Matt_Aufderheite. Wenn bei denen jemand etwas über shader wissen wollte, oder etwas nich 100% verstanden hat, wurde man auch nur mit einer lächerlichen Antwort wie (sinngemäß) "Du hast null Plan, lass es sein!" abgespeist. Anscheinend hält sich jeder, der Shader gut beherrscht, für den totalen Alleskönner.

Verzeihung, dass ich hier nur eine Möglichkeit aufgezeigt habe, wie man mehrere Texturen kombinieren kann. Das nächste mal verweise ich gern auf deine langjährige Erfahrung!

Aber anstatt einen Shader mal hochzuladen, wird einfach nur behauptet, es ist zu schwer. Es hätten sicherlich noch andere Leute daran interesse.
Posted By: Hummel

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 14:35

Vieleicht hatte ich deinen Post einfach nur falsch verstanden, aber der kam ziemlich sarkastisch rüber, was wiederum arrogant von deiner Seite aus erschien.
Sollte dem nicht so gewesen sein, kannst du vlt jetzt meine Reaktion nachvollziehen.

Und nur weil ich dich auf das ein oder andere hinweiße, liegt es noch lange nicht in meinem Interesse dich als "Nichts-Könner" hin zu stellen.

Posted By: Widi

Re: Searching HLSL Terrain Multitexturing... - 05/12/10 16:56

Ich finde es gut wenn hier auch ein bisschen Shadercode gezeigt wird. Beschäftige mich auch seit einiger Zeit mit Shaderprogrammierung und wenn man anderen Code sieht lernt man doch immer wieder etwas. Sicher gibt es meistens eine bessere Lösung (ändere selber die meisten Shader auf meine Bedürftnisse ab), aber lieber ein "unvollständiger" Code als garkeinen.

Hummel UND wdlmaster haben mir beide schon einigemale geholfen, also Danke nochmals vielmals an euch beide...
Posted By: ChrisB

Re: Searching HLSL Terrain Multitexturing... - 05/13/10 14:40

Da hier die shaderrubrik im wiki angesprochen wurde: Währt ihr so freundlich eure Shader ins wiki einzutragen wenn ihr sie eh veröffentlicht? Auch wenn sie nicht für jedes Projekt geeignet sind so kann man sie trotzdem zum lernen benutzen. Außerdem gibts keine Probleme wenn ihr eure demos von eurem webspace löscht oder ähnliches. wink
Posted By: djfeeler

Re: Searching HLSL Terrain Multitexturing... - 08/06/10 13:13

Hello !

Have you an example with the materials effect and file BMAP and skin to pass textures them in the shader ?

thanks in advance djfeeler
Posted By: Nidhogg

Re: Searching HLSL Terrain Multitexturing... - 08/06/10 14:11

See previous page there is a link to download the demo. If it's still available.
© 2024 lite-C Forums